afs/_pts.pyx

   1 from afs cimport *
   2
   3 cdef import from "afs/ptuser.h":
   4     enum:
   5         PR_MAXNAMELEN
   6
   7     ctypedef char prname[PR_MAXNAMELEN]
   8
   9     struct namelist:
  10         unsigned int namelist_len
  11         prname *namelist_val
  12
  13     struct idlist:
  14         unsigned int idlist_len
  15         afs_int32 *idlist_val
  16
  17     int ubik_PR_NameToID(ubik_client *, afs_int32, namelist *, idlist *)
  18     int ubik_PR_IDToName(ubik_client *, afs_int32, idlist *, namelist *)
  19
  20 cdef class PTS:
  21     cdef ubik_client * client
  22
  23     def __cinit__(self, cell=None, sec=1):
  24         cdef afs_int32 code
  25         cdef afsconf_dir *cdir
  26         cdef afsconf_cell info
  27         cdef char * c_cell
  28         cdef ktc_principal prin
  29         cdef ktc_token token
  30         cdef rx_securityClass *sc
  31         cdef rx_connection *serverconns[MAXSERVERS]
  32         cdef int i
  33
  34         if cell is None:
  35             c_cell = NULL
  36         else:
  37             c_cell = cell
  38
  39         self.client = NULL
  40
  41         code = rx_Init(0)
  42         if code != 0:
  43             raise Exception(code, "Error initializing Rx")
  44
  45         cdir = afsconf_Open(AFSDIR_CLIENT_ETC_DIRPATH)
  46         if cdir is NULL:
  47             raise OSError(errno,
  48                           "Error opening configuration directory (%s): %s" % \
  49                               (AFSDIR_CLIENT_ETC_DIRPATH, strerror(errno)))
  50         code = afsconf_GetCellInfo(cdir, c_cell, "afsprot", &info)
  51         if code != 0:
  52             raise Exception(code, "GetCellInfo: %s" % afs_error_message(code))
  53
  54         if sec > 0:
  55             strncpy(prin.cell, info.name, sizeof(prin.cell))
  56             prin.instance[0] = 0
  57             strncpy(prin.name, "afs", sizeof(prin.name))
  58
  59             code = ktc_GetToken(&prin, &token, sizeof(token), NULL);
  60             if code != 0:
  61                 if sec >= 2:
  62                     # No really - we wanted authentication
  63                     raise Exception(code, "Failed to get token for service AFS: %s" % afs_error_message(code))
  64                 sec = 0
  65             else:
  66                 if sec == 3:
  67                     level = rxkad_crypt
  68                 else:
  69                     level = rxkad_clear
  70                 sc = rxkad_NewClientSecurityObject(level, &token.sessionKey,
  71                                                    token.kvno, token.ticketLen,
  72                                                    token.ticket)
  73
  74         if sec == 0:
  75             sc = rxnull_NewClientSecurityObject()
  76         else:
  77             sec = 2
  78
  79         memset(serverconns, 0, sizeof(serverconns))
  80         for 0 <= i < info.numServers:
  81             serverconns[i] = rx_NewConnection(info.hostAddr[i].sin_addr.s_addr,
  82                                               info.hostAddr[i].sin_port,
  83                                               PRSRV,
  84                                               sc,
  85                                               sec)
  86
  87         code = ubik_ClientInit(serverconns, &self.client)
  88         if code != 0:
  89             raise Exception("Failed to initialize ubik connection to Protection server: %s" % afs_error_message(code))
  90
  91         code = rxs_Release(sc)
  92
  93     def __dealloc__(self):
  94         ubik_ClientDestroy(self.client)
  95         rx_Finalize()
  96
  97     def NameToId(self, name):
  98         cdef namelist lnames
  99         cdef idlist lids
 100         cdef afs_int32 code, id
 101         name = name.lower()
 102
 103         lids.idlist_len = 0
 104         lids.idlist_val = NULL
 105         lnames.namelist_len = 1
 106         lnames.namelist_val = <prname *>malloc(PR_MAXNAMELEN)
 107         strncpy(lnames.namelist_val[0], name, PR_MAXNAMELEN)
 108         code = ubik_PR_NameToID(self.client, 0, &lnames, &lids)
 109         if lids.idlist_val is not NULL:
 110             id = lids.idlist_val[0]
 111             free(lids.idlist_val)
 112         if code != 0:
 113             raise Exception("Failed to lookup PTS name: %s" % afs_error_message(code))
 114         return id
 115
 116     def IdToName(self, id):
 117         cdef namelist lnames
 118         cdef idlist lids
 119         cdef afs_int32 code
 120         cdef char name[PR_MAXNAMELEN]
 121
 122         lids.idlist_len = 1
 123         lids.idlist_val = <afs_int32 *>malloc(sizeof(afs_int32))
 124         lids.idlist_val[0] = id
 125         lnames.namelist_len = 0
 126         lnames.namelist_val = NULL
 127         code = ubik_PR_IDToName(self.client, 0, &lids, &lnames)
 128         if lnames.namelist_val is not NULL:
 129             strncpy(name, lnames.namelist_val[0], sizeof(name))
 130             free(lnames.namelist_val)
 131         if lids.idlist_val is not NULL:
 132             free(lids.idlist_val)
 133         if code != 0:
 134             raise Exception("Failed to lookup PTS ID: %s" % afs_error_message(code))
 135         return name