Add SetMax.

[invirt/packages/python-afs.git] / afs / _pts.pyx

diff --git a/afs/_pts.pyx b/afs/_pts.pyx
index 5ba1c4f..a48c64e 100644 (file)
--- a/afs/_pts.pyx
+++ b/afs/_pts.pyx
@@ -20,6 +20,14 @@ cdef import from "afs/ptuser.h":
         unsigned int idlist_len
         afs_int32 *idlist_val
 
+    struct prcheckentry:
+        afs_int32 flags
+        afs_int32 id
+        afs_int32 owner
+        afs_int32 creator
+        afs_int32 ngroups
+        afs_int32 count
+
     int ubik_PR_NameToID(ubik_client *, afs_int32, namelist *, idlist *)
     int ubik_PR_IDToName(ubik_client *, afs_int32, idlist *, namelist *)
     int ubik_PR_INewEntry(ubik_client *, afs_int32, char *, afs_int32, afs_int32)
@@ -29,6 +37,11 @@ cdef import from "afs/ptuser.h":
     int ubik_PR_RemoveFromGroup(ubik_client *, afs_int32, afs_int32, afs_int32)
     int ubik_PR_ListElements(ubik_client *, afs_int32, afs_int32, prlist *, afs_int32 *)
     int ubik_PR_ListOwned(ubik_client *, afs_int32, afs_int32, prlist *, afs_int32 *)
+    int ubik_PR_ListEntry(ubik_client *, afs_int32, afs_int32, prcheckentry *)
+    int ubik_PR_ChangeEntry(ubik_client *, afs_int32, afs_int32, char *, afs_int32, afs_int32)
+    int ubik_PR_IsAMemberOf(ubik_client *, afs_int32, afs_int32, afs_int32, afs_int32 *)
+    int ubik_PR_ListMax(ubik_client *, afs_int32, afs_int32 *, afs_int32 *)
+    int ubik_PR_SetMax(ubik_client *, afs_int32, afs_int32, afs_int32)
 
 cdef import from "afs/pterror.h":
     enum:
@@ -37,6 +50,40 @@ cdef import from "afs/pterror.h":
 
     void initialize_PT_error_table()
 
+cdef class PTEntry:
+    cdef public afs_int32 flags
+    cdef public afs_int32 id
+    cdef public afs_int32 owner
+    cdef public afs_int32 creator
+    cdef public afs_int32 ngroups
+    cdef public afs_int32 count
+
+cdef int _ptentry_from_c(PTEntry p_entry, prcheckentry c_entry) except -1:
+    if p_entry is None:
+        raise TypeError
+        return -1
+
+    p_entry.flags = c_entry.flags
+    p_entry.id = c_entry.id
+    p_entry.owner = c_entry.owner
+    p_entry.creator = c_entry.creator
+    p_entry.ngroups = c_entry.ngroups
+    p_entry.count = c_entry.count
+    return 0
+
+cdef int _ptentry_to_c(prcheckentry * c_entry, PTEntry p_entry) except -1:
+    if p_entry is None:
+        raise TypeError
+        return -1
+
+    c_entry.flags = p_entry.flags
+    c_entry.id = p_entry.id
+    c_entry.owner = p_entry.owner
+    c_entry.creator = p_entry.creator
+    c_entry.ngroups = p_entry.ngroups
+    c_entry.count = p_entry.count
+    return 0
+
 cdef class PTS:
     """
     A PTS object is essentially a handle to talk to the server in a
@@ -310,3 +357,90 @@ cdef class PTS:
             raise Exception("Failed to get owned entities: %s" % afs_error_message(code))
 
         return owned
+
+    def ListEntry(self, id):
+        """
+        Load a PTEntry instance with information about the provided
+        ID.
+        """
+        cdef afs_int32 code
+        cdef prcheckentry centry
+        cdef object entry = PTEntry()
+
+        code = ubik_PR_ListEntry(self.client, 0, id, &centry)
+        if code != 0:
+            raise Exception("Error getting entity info: %s" % afs_error_message(code))
+
+        _ptentry_from_c(entry, centry)
+        return entry
+
+    def ChangeEntry(self, id, newname=None, newid=None, newoid=None):
+        """
+        Change the name, ID, and/or owner of a PTS entity.
+
+        For any of newname, newid, and newoid which aren't specified
+        or ar None, the value isn't changed.
+        """
+        cdef afs_int32 code
+        cdef afs_int32 c_newid = 0, c_newoid = 0
+        cdef char * c_newname
+
+        if newname is None:
+            newname = self.IdToName(id)
+        c_newname = newname
+        if newid is not None:
+            c_newid = newid
+        if newoid is not None:
+            c_newoid = newoid
+
+        code = ubik_PR_ChangeEntry(self.client, 0, id, c_newname, c_newoid, c_newid)
+        if code != 0:
+            raise Exception("Error changing entity info: %s" % afs_error_message(code))
+
+    def IsAMemberOf(self, uid, gid):
+        """
+        Return True if the given uid is a member of the given gid.
+        """
+        cdef afs_int32 code
+        cdef afs_int32 flag
+
+        code = ubik_PR_IsAMemberOf(self.client, 0, uid, gid, &flag)
+        if code != 0:
+            raise Exception("Error testing membership: %s" % afs_error_message(code))
+
+        return bool(flag)
+
+    def ListMax(self):
+        """
+        Return a tuple of the maximum user ID and the maximum group
+        ID currently assigned.
+        """
+        cdef afs_int32 code, uid, gid
+
+        code = ubik_PR_ListMax(self.client, 0, &uid, &gid)
+        if code != 0:
+            raise Exception("Error looking up max uid/gid: %s" % afs_error_message(code))
+
+        return (uid, gid)
+
+    def SetMaxUserId(self, id):
+        """
+        Set the maximum currently assigned user ID (the next
+        automatically assigned UID will be id + 1)
+        """
+        cdef afs_int32 code
+
+        code = ubik_PR_SetMax(self.client, 0, id, 0)
+        if code != 0:
+            raise Exception("Error setting max uid: %s" % afs_error_message(code))
+
+    def SetMaxGroupId(self, id):
+        """
+        Set the maximum currently assigned user ID (the next
+        automatically assigned UID will be id + 1)
+        """
+        cdef afs_int32 code
+
+        code = ubik_PR_SetMax(self.client, 0, id, PRGRP)
+        if code != 0:
+            raise Exception("Error setting max gid: %s" % afs_error_message(code))