afs/_pts.pyx

   1 from afs cimport *
   2
   3 cdef import from "afs/ptuser.h":
   4     enum:
   5         PR_MAXNAMELEN
   6
   7     enum:
   8         PRGRP
   9
  10     enum:
  11         ANONYMOUSID
  12
  13     ctypedef char prname[PR_MAXNAMELEN]
  14
  15     struct namelist:
  16         unsigned int namelist_len
  17         prname *namelist_val
  18
  19     struct idlist:
  20         unsigned int idlist_len
  21         afs_int32 *idlist_val
  22
  23     int ubik_PR_NameToID(ubik_client *, afs_int32, namelist *, idlist *)
  24     int ubik_PR_IDToName(ubik_client *, afs_int32, idlist *, namelist *)
  25     int ubik_PR_INewEntry(ubik_client *, afs_int32, char *, afs_int32, afs_int32)
  26     int ubik_PR_NewEntry(ubik_client *, afs_int32, char *, afs_int32, afs_int32, afs_int32 *)
  27
  28 cdef class PTS:
  29     cdef ubik_client * client
  30
  31     def __cinit__(self, cell=None, sec=1):
  32         cdef afs_int32 code
  33         cdef afsconf_dir *cdir
  34         cdef afsconf_cell info
  35         cdef char * c_cell
  36         cdef ktc_principal prin
  37         cdef ktc_token token
  38         cdef rx_securityClass *sc
  39         cdef rx_connection *serverconns[MAXSERVERS]
  40         cdef int i
  41
  42         if cell is None:
  43             c_cell = NULL
  44         else:
  45             c_cell = cell
  46
  47         self.client = NULL
  48
  49         code = rx_Init(0)
  50         if code != 0:
  51             raise Exception(code, "Error initializing Rx")
  52
  53         cdir = afsconf_Open(AFSDIR_CLIENT_ETC_DIRPATH)
  54         if cdir is NULL:
  55             raise OSError(errno,
  56                           "Error opening configuration directory (%s): %s" % \
  57                               (AFSDIR_CLIENT_ETC_DIRPATH, strerror(errno)))
  58         code = afsconf_GetCellInfo(cdir, c_cell, "afsprot", &info)
  59         if code != 0:
  60             raise Exception(code, "GetCellInfo: %s" % afs_error_message(code))
  61
  62         if sec > 0:
  63             strncpy(prin.cell, info.name, sizeof(prin.cell))
  64             prin.instance[0] = 0
  65             strncpy(prin.name, "afs", sizeof(prin.name))
  66
  67             code = ktc_GetToken(&prin, &token, sizeof(token), NULL);
  68             if code != 0:
  69                 if sec >= 2:
  70                     # No really - we wanted authentication
  71                     raise Exception(code, "Failed to get token for service AFS: %s" % afs_error_message(code))
  72                 sec = 0
  73             else:
  74                 if sec == 3:
  75                     level = rxkad_crypt
  76                 else:
  77                     level = rxkad_clear
  78                 sc = rxkad_NewClientSecurityObject(level, &token.sessionKey,
  79                                                    token.kvno, token.ticketLen,
  80                                                    token.ticket)
  81
  82         if sec == 0:
  83             sc = rxnull_NewClientSecurityObject()
  84         else:
  85             sec = 2
  86
  87         memset(serverconns, 0, sizeof(serverconns))
  88         for 0 <= i < info.numServers:
  89             serverconns[i] = rx_NewConnection(info.hostAddr[i].sin_addr.s_addr,
  90                                               info.hostAddr[i].sin_port,
  91                                               PRSRV,
  92                                               sc,
  93                                               sec)
  94
  95         code = ubik_ClientInit(serverconns, &self.client)
  96         if code != 0:
  97             raise Exception("Failed to initialize ubik connection to Protection server: %s" % afs_error_message(code))
  98
  99         code = rxs_Release(sc)
 100
 101     def __dealloc__(self):
 102         ubik_ClientDestroy(self.client)
 103         rx_Finalize()
 104
 105     def NameToId(self, name):
 106         cdef namelist lnames
 107         cdef idlist lids
 108         cdef afs_int32 code, id
 109         name = name.lower()
 110
 111         lids.idlist_len = 0
 112         lids.idlist_val = NULL
 113         lnames.namelist_len = 1
 114         lnames.namelist_val = <prname *>malloc(PR_MAXNAMELEN)
 115         strncpy(lnames.namelist_val[0], name, PR_MAXNAMELEN)
 116         code = ubik_PR_NameToID(self.client, 0, &lnames, &lids)
 117         if lids.idlist_val is not NULL:
 118             id = lids.idlist_val[0]
 119             free(lids.idlist_val)
 120         if code != 0:
 121             raise Exception("Failed to lookup PTS name: %s" % afs_error_message(code))
 122         return id
 123
 124     def IdToName(self, id):
 125         cdef namelist lnames
 126         cdef idlist lids
 127         cdef afs_int32 code
 128         cdef char name[PR_MAXNAMELEN]
 129
 130         lids.idlist_len = 1
 131         lids.idlist_val = <afs_int32 *>malloc(sizeof(afs_int32))
 132         lids.idlist_val[0] = id
 133         lnames.namelist_len = 0
 134         lnames.namelist_val = NULL
 135         code = ubik_PR_IDToName(self.client, 0, &lids, &lnames)
 136         if lnames.namelist_val is not NULL:
 137             strncpy(name, lnames.namelist_val[0], sizeof(name))
 138             free(lnames.namelist_val)
 139         if lids.idlist_val is not NULL:
 140             free(lids.idlist_val)
 141         if code != 0:
 142             raise Exception("Failed to lookup PTS ID: %s" % afs_error_message(code))
 143         return name
 144
 145     def CreateUser(self, name, id=None):
 146         cdef afs_int32 code
 147         cdef afs_int32 cid
 148         name = name[:PR_MAXNAMELEN].lower()
 149
 150         if id is not None:
 151             cid = id
 152
 153         if id is not None:
 154             code = ubik_PR_INewEntry(self.client, 0, name, cid, 0)
 155         else:
 156             code = ubik_PR_NewEntry(self.client, 0, name, 0, 0, &cid)
 157
 158         if code != 0:
 159             raise Exception("Failed to create user: %s" % afs_error_message(code))
 160         return cid
 161
 162     def CreateGroup(self, name, owner, id=None):
 163         cdef afs_int32 code, cid
 164
 165         name = name[:PR_MAXNAMELEN].lower()
 166         oid = self.NameToId(owner)
 167         if oid == ANONYMOUSID:
 168             raise Exception("Error creating group: owner does not exist")
 169
 170         if id is not None:
 171             cid = id
 172             code = ubik_PR_INewEntry(self.client, 0, name, cid, oid)
 173         else:
 174             code = ubik_PR_NewEntry(self.client, 0, name, PRGRP, oid, &cid)
 175
 176         if code != 0:
 177             raise Exception("Failed to create group: %s" % afs_error_message(code))
 178         return cid