afs/_pts.pyx

   1 from afs cimport *
   2
   3 cdef import from "afs/ptuser.h":
   4     enum:
   5         PR_MAXNAMELEN
   6
   7     enum:
   8         PRGRP
   9
  10     enum:
  11         ANONYMOUSID
  12
  13     ctypedef char prname[PR_MAXNAMELEN]
  14
  15     struct namelist:
  16         unsigned int namelist_len
  17         prname *namelist_val
  18
  19     struct idlist:
  20         unsigned int idlist_len
  21         afs_int32 *idlist_val
  22
  23     int ubik_PR_NameToID(ubik_client *, afs_int32, namelist *, idlist *)
  24     int ubik_PR_IDToName(ubik_client *, afs_int32, idlist *, namelist *)
  25     int ubik_PR_INewEntry(ubik_client *, afs_int32, char *, afs_int32, afs_int32)
  26     int ubik_PR_NewEntry(ubik_client *, afs_int32, char *, afs_int32, afs_int32, afs_int32 *)
  27     int ubik_PR_Delete(ubik_client *, afs_int32, afs_int32)
  28
  29 cdef class PTS:
  30     cdef ubik_client * client
  31
  32     def __cinit__(self, cell=None, sec=1):
  33         cdef afs_int32 code
  34         cdef afsconf_dir *cdir
  35         cdef afsconf_cell info
  36         cdef char * c_cell
  37         cdef ktc_principal prin
  38         cdef ktc_token token
  39         cdef rx_securityClass *sc
  40         cdef rx_connection *serverconns[MAXSERVERS]
  41         cdef int i
  42
  43         if cell is None:
  44             c_cell = NULL
  45         else:
  46             c_cell = cell
  47
  48         self.client = NULL
  49
  50         code = rx_Init(0)
  51         if code != 0:
  52             raise Exception(code, "Error initializing Rx")
  53
  54         cdir = afsconf_Open(AFSDIR_CLIENT_ETC_DIRPATH)
  55         if cdir is NULL:
  56             raise OSError(errno,
  57                           "Error opening configuration directory (%s): %s" % \
  58                               (AFSDIR_CLIENT_ETC_DIRPATH, strerror(errno)))
  59         code = afsconf_GetCellInfo(cdir, c_cell, "afsprot", &info)
  60         if code != 0:
  61             raise Exception(code, "GetCellInfo: %s" % afs_error_message(code))
  62
  63         if sec > 0:
  64             strncpy(prin.cell, info.name, sizeof(prin.cell))
  65             prin.instance[0] = 0
  66             strncpy(prin.name, "afs", sizeof(prin.name))
  67
  68             code = ktc_GetToken(&prin, &token, sizeof(token), NULL);
  69             if code != 0:
  70                 if sec >= 2:
  71                     # No really - we wanted authentication
  72                     raise Exception(code, "Failed to get token for service AFS: %s" % afs_error_message(code))
  73                 sec = 0
  74             else:
  75                 if sec == 3:
  76                     level = rxkad_crypt
  77                 else:
  78                     level = rxkad_clear
  79                 sc = rxkad_NewClientSecurityObject(level, &token.sessionKey,
  80                                                    token.kvno, token.ticketLen,
  81                                                    token.ticket)
  82
  83         if sec == 0:
  84             sc = rxnull_NewClientSecurityObject()
  85         else:
  86             sec = 2
  87
  88         memset(serverconns, 0, sizeof(serverconns))
  89         for 0 <= i < info.numServers:
  90             serverconns[i] = rx_NewConnection(info.hostAddr[i].sin_addr.s_addr,
  91                                               info.hostAddr[i].sin_port,
  92                                               PRSRV,
  93                                               sc,
  94                                               sec)
  95
  96         code = ubik_ClientInit(serverconns, &self.client)
  97         if code != 0:
  98             raise Exception("Failed to initialize ubik connection to Protection server: %s" % afs_error_message(code))
  99
 100         code = rxs_Release(sc)
 101
 102     def __dealloc__(self):
 103         ubik_ClientDestroy(self.client)
 104         rx_Finalize()
 105
 106     def NameToId(self, name):
 107         cdef namelist lnames
 108         cdef idlist lids
 109         cdef afs_int32 code, id
 110         name = name.lower()
 111
 112         lids.idlist_len = 0
 113         lids.idlist_val = NULL
 114         lnames.namelist_len = 1
 115         lnames.namelist_val = <prname *>malloc(PR_MAXNAMELEN)
 116         strncpy(lnames.namelist_val[0], name, PR_MAXNAMELEN)
 117         code = ubik_PR_NameToID(self.client, 0, &lnames, &lids)
 118         if lids.idlist_val is not NULL:
 119             id = lids.idlist_val[0]
 120             free(lids.idlist_val)
 121         if code != 0:
 122             raise Exception("Failed to lookup PTS name: %s" % afs_error_message(code))
 123         return id
 124
 125     def IdToName(self, id):
 126         cdef namelist lnames
 127         cdef idlist lids
 128         cdef afs_int32 code
 129         cdef char name[PR_MAXNAMELEN]
 130
 131         lids.idlist_len = 1
 132         lids.idlist_val = <afs_int32 *>malloc(sizeof(afs_int32))
 133         lids.idlist_val[0] = id
 134         lnames.namelist_len = 0
 135         lnames.namelist_val = NULL
 136         code = ubik_PR_IDToName(self.client, 0, &lids, &lnames)
 137         if lnames.namelist_val is not NULL:
 138             strncpy(name, lnames.namelist_val[0], sizeof(name))
 139             free(lnames.namelist_val)
 140         if lids.idlist_val is not NULL:
 141             free(lids.idlist_val)
 142         if code != 0:
 143             raise Exception("Failed to lookup PTS ID: %s" % afs_error_message(code))
 144         return name
 145
 146     def CreateUser(self, name, id=None):
 147         cdef afs_int32 code
 148         cdef afs_int32 cid
 149         name = name[:PR_MAXNAMELEN].lower()
 150
 151         if id is not None:
 152             cid = id
 153
 154         if id is not None:
 155             code = ubik_PR_INewEntry(self.client, 0, name, cid, 0)
 156         else:
 157             code = ubik_PR_NewEntry(self.client, 0, name, 0, 0, &cid)
 158
 159         if code != 0:
 160             raise Exception("Failed to create user: %s" % afs_error_message(code))
 161         return cid
 162
 163     def CreateGroup(self, name, owner, id=None):
 164         cdef afs_int32 code, cid
 165
 166         name = name[:PR_MAXNAMELEN].lower()
 167         oid = self.NameToId(owner)
 168         if oid == ANONYMOUSID:
 169             raise Exception("Error creating group: owner does not exist")
 170
 171         if id is not None:
 172             cid = id
 173             code = ubik_PR_INewEntry(self.client, 0, name, cid, oid)
 174         else:
 175             code = ubik_PR_NewEntry(self.client, 0, name, PRGRP, oid, &cid)
 176
 177         if code != 0:
 178             raise Exception("Failed to create group: %s" % afs_error_message(code))
 179         return cid
 180
 181     def Delete(self, id):
 182         cdef afs_int32 code
 183
 184         code = ubik_PR_Delete(self.client, 0, id)
 185         if code != 0:
 186             raise Exception("Failed to delete user: %s" % afs_error_message(code))